Function Copy_PasteTranspose()
	//"Pastes" selected data from top table into new waves with X and Y transposed
	//CAUTION: overwrites waves from previous uses, so rename the waves or cut and repaste the data as
	//  soon as you use this
	
	VARIABLE Temp1, Temp2, NumCols
	STRING PTWaveSourceName, TransposedScrap=""
	GetSelection table,$WinName(0,2), 3
	if (V_flag==1)
		NumCols=V_endCol-V_startCol+1
		for (Temp1=V_startRow;Temp1<=V_endRow;Temp1+=1)
			make /O/N=(NumCols) $("PTTempWave_Row"+num2str(Temp1))
			AppendToTable $("PTTempWave_Row"+num2str(Temp1))
		endfor
		for (Temp1=0;Temp1<NumCols;Temp1+=1)
			PTWaveSourceName=StringFromList(Temp1, S_selection)
			PTWaveSourceName=PTWaveSourceName[0,strlen(PTWaveSourceName)-3]
			WAVE PTWaveSource=$PTWaveSourceName
			for (Temp2=V_startRow;Temp2<=V_endRow;Temp2+=1)
				WAVE PTWave=$("PTTempWave_Row"+num2str(Temp2))
				PTWave[Temp1]=PTWaveSource[Temp2]
				TransposedScrap+=num2str(PTWaveSource[Temp2])+"\t"
			endfor
			TransposedScrap+="\r"
		endfor
		TransposedScrap=TransposedScrap[0,strlen(TransposedScrap)-3]//remove last return
		PutScrapText TransposedScrap
	endif
end